Madness.nl | Scripts - Universele Database Viewer

Hoofdmenu

•  Home
•  ASP Tips
•  Artikelen
•  ASP Lessen
•  Scripts
•  Opleidingen
•  Resources
•  Madness Forum
•  Nieuws
•  Adverteren?

Members

Inloggen
Registreer je nu!
Wachtwoord vergeten?

Laatste reacties

26-11 ASP en formulieren
09-06 ASP en databases
14-03 SQL de basis
28-02 Formulier > E-mail
07-08 Nieuwe versie Madne...

Madness.nl Forum

21:41 Te mooi om waar te ..
08:47 application
08:46 Domein Hosting
08:45 USB webserver
08:45 Eigen Scripts
08:44 Database paging
10:21 Even voorstellen?
10:18 Re: It agree, it is..
10:16 ASp.NET MVC
20:42 GPS-applicatie VB v..

Universele Database Viewer

Terug naar scripts

Auteur: Ramon
Geplaatst op: 13-6-2002
Laatste update: 17-8-2003 18:21:15
Gerelateerd artikel: ASP en Getrows
Aantal keer bekeken: 45973
Download script (zip file)

Universele Database Viewer

Omschrijving: Dit script kan gebruikt worden om een willekeurige tabel te laten zien. Bovenin het script moet de tabelnaam opgegevens worden en vervolgens worden de gegevens uit de tabel getoond in een sorteerbare tabel.

Script:

Pagina: showdb.asp

<html><head><TITLE>Universele database viewer</TITLE></head><body>
<% 
' Vul hier de naam van de tabel in die bekeken moet worden.
TabelNaam = "NaamTabel"

sorteren = request.querystring("sort")
' Zet de connectiestring in de variabele. Hier is dit dus een OLEDB connectie.
accessDB = server.mappath("database.mdb")
strCon = "PROVIDER=Microsoft.Jet.OLEDB.4.0;DATA SOURCE="
strCon = strCon & accessDB & ";"

if sorteren = "" then
	SQL = "SELECT * FROM " & TabelNaam
else
	SQL = "SELECT * FROM " & TabelNaam &" ORDER BY " & sorteren
end if

' Deze waarden woorden gebruikt wanneer er geen waarde in een veld staat.
showblank="&nbsp;"
shownull="&nbsp;"

' Maak een serverobject aan voor de connectie (ObjectConnectie -> objCon)
Dim objCon
Set objCon = Server.CreateObject ( "ADODB.Connection" )
objCon.open strCon

'Maak een recordset aan met de gegevens uit de database.
set objRec=objCon.execute(SQL)

' Als er geen gegevens in de database staan geeft dit dan aan.
If  objRec.eof then
   response.write "Geen records gevonden!<br>"
   response.write "<br>Er kan geen tabel gemaakt worden..."
   
   ' Roep de functie aan die de recordset en verbinding sluit.
   Call SluitAlles
   
   ' Stop met het uitvoeren van verdere code, omdat er niets meer te doen is.
   response.end
end if

response.write "Gesorteerd op: " & sorteren & vbcrlf
response.write "<table border='1'><tr>" & vbcrlf
'Zet in de bovenste rij de veldnamen
for each tabel in objRec.fields
	' maak een link van de bovenste rij en geef de sorteer variable mee.
   response.write "<td><b>"
   response.write "<a href='showdb.asp?sort=" & tabel.name & "'>" & tabel.name & "</a>" & vbcrlf
   response.write "</b></td>" & vbcrlf
next
response.write "</tr>" & vbcrlf

' Nu halen we alle records uit de database en zetten ze in AlleData
AlleData=objRec.getrows

' Ga naar de functie die alles afsluit.<br>
' We hebben nu alle gegevens dus we hebben geen<br>
' recordset of verbinding meer nodig.
Call SluitAlles

' Tel het aantal kolommen
AantalKolommen=ubound(AlleData,1)

' Tel het aantal rijen.
AantalRijen=ubound(AlleData,2)

' Loop door de rijen heen.
FOR RijTeller= 0 TO AantalRijen
   response.write "<tr>" & vbcrlf
   
   ' Loop door de kolommen heen.
   FOR KolomTeller=0 to AantalKolommen
      
	  ' Zet de waarde uit kolomnummer, rijnummer in de variabele HuidigVeld.
	  HuidigVeld=AlleData(KolomTeller,RijTeller)
      
	  'Als het huidige veld NULL is laat dan shownull zien.
	  if isnull(HuidigVeld) then
         HuidigVeld=shownull
      end if
	  
	  ' Als het veld leeg is laat dan een nbsp zien.
      if trim(HuidigVeld)="" then
         HuidigVeld=showblank
      end if
	  'Bouw de rest van de tabel
      response.write "<td valign=top>" 
	  
	  ' Plaats de waarde in de tabel.
      response.write HuidigVeld
      response.write "</td>" & vbcrlf
   NEXT
   response.write "</tr>" & vbcrlf
NEXT
response.write "</table>" 
%>
</body></html>
<%

' Sluit de recordset af en verbreek de verbinding met de database.
SUB SluitAlles
   objRec.close
   set objRec=nothing
   objCon.close
   set objCon=nothing
END SUB
%>

Reacties

Reacties: Universele Database Viewer (Aantal reacties: 11 )
» Nieuwe reactie	View Mode : \| \|

Door: Annette

Dec 28, 22:04

Hai ,
Ik heb op internet een hele gave tabel editor gevonden. Zie http://www.wellige.com/tom/ute/
Deze editor is erg handig in gebruik en nog gratis ook.

Het is wel een gevorderde manier van programmeren maar is zeer eenvoudig in je eigen pagina's in te bouwen.
Groetjes oja erg leuke site. Ik wil gaan beginnen met ASP.NET Ik programeer al wel in ASP en dit is een fijne site om mijn eerst stapjes te leren.

(Reply...)

Door: Ramon (Admin)

Dec 29, 15:46

Ik gebruik een vergelijkbare:
http://www.2enetworx.com/dev/projects/tableeditor.asp

Ik gebruik hem zelf om af en toe hier wat te editen.

Ik hoop binnenkort meer ASP.NET lessen online te zetten. Ik moet het alleen zelf nog ff leren

(Reply...)

Door: bertdevil

Okt 23, 15:17

Thx voor dit script, maar hoe krijg je voor elk record een edit en delete knop

(Reply...)

Door: Ramon (Admin)

Okt 23, 20:03

KLIK HIER

(Reply...)

Door: bertdevil

Okt 24, 09:50

oops

(Reply...)

Door: Gast

Feb 26, 23:45

Op een gegeven moment staat er dit in de berichten.asp file: for each tabel in objRec.Fields
Nou moet ik hetzelfde hebben, maar niet ALLE (each tabel) tabellen. Hoe kan ik i.p.v each tabel ervoor zorgen dat ik alleen bepaalde tabellen krijg?

(Reply...)

Door: Ramon (Admin)

Feb 27, 10:57

Die kan je met het SQL statement selecteren. Alles resultaten van de query worden getoond. Dus bijvoorbeeld

select veld1, veld2 from tabel1

(Reply...)

Door: marmachine

Jun 2, 15:48

Hoe maak ik concreet een selectie? Mijn doel is om alleen de laatste 5 regels van een specifieke tabel te tonen. De laatste regels zijn dynamisch... dus moet het eerst worden vastgesteld WAT de laatste 5 id's zijn! Kan iemand een iedeetje geven misschien?

(Reply...)

Door: Gast

Okt 24, 13:56

Ik zie altijd overal heel veel voorbeelden hoe een database te benaderen. Maar is er iemand die weet hoe je een access database benaderd met een mdw file?

(Reply...)

Door: Ramon (Admin)

Okt 24, 21:23

Info is te vinden op http://support.microsoft.com/default.aspx?scid=KB;EN-US;Q163159&

(Reply...)

Scripts

Overzicht
Script insturen

Zoeken

Zoekterm(en):