Hoofdmenu
•  Home
•  ASP Tips
•  Artikelen
•  ASP Lessen
•  Scripts
•  Opleidingen
•  Resources
•  Madness Forum
•  Nieuws
•  Adverteren?

Members

Inloggen
Registreer je nu!
Wachtwoord vergeten?

Laatste reacties
26-11 ASP en formulieren
09-06 ASP en databases
14-03 SQL de basis
28-02 Formulier > E-mail
07-08 Nieuwe versie Madne...

Madness.nl Forum
08:47 application
08:46 Domein Hosting
08:45 USB webserver
08:45 Eigen Scripts
08:44 Database paging
10:21 Even voorstellen?
10:18 Re: It agree, it is..
10:16 ASp.NET MVC
20:42 GPS-applicatie VB v..
10:10 webservice


Database paging Terug naar artikelen
Geplaatst door: Ramon
Geplaatst op: 23-12-2002
Laatste update: 3-4-2003 11:31:35
Aantal keer bekeken: 49439
 Database paging

Stel je hebt een database met 2000 records en wilt deze records op een website laten zien. Voor de bezoeker van de website is het niet fijn wanneer er in één keer 2000 records op het scherm verschijnen. Het is beter om telkens 20 records te laten zien en dat de bezoeker kan navigeren. Dit principe heet paging. Dit is dus het opdelen van de records in verschillende pagina's. Het volgende voorbeeld laat zien hoe dit in z'n werk gaat. Dit artikel is gebaseerd op een artikel van asp101.

Adovbs.inc is een standaard bestand van Microsoft. In dit bestand staan alle constanten gedefineerd. Termen als adOpenStatic en adLockReadOnly staan hierin. Het bestand is hier al textbestand te downloaden.

In dit voorbeeld is er weer gebruik gemaakt van de voorbeeld database.

paging.asp

<!-- #include file="adovbs.inc" -->
<html>
<head>
<title>Madness.nl | Database Paging</title>
</head><body>

<%
' Declareren van de variabelen
Dim strCon
Dim objCon
Dim accessDB
Dim aantalRecords
Dim aantalPaginas
Dim huidigePagina
Dim strSQL
Dim objRec
Dim recordsGetoond
Dim I

' Zet de connectiestring in de variabele. Hier is dit dus een ODBC connectie.
accessDB = server.mappath("/voorbeeld/voorbeeld.mdb")
strCon = "PROVIDER=Microsoft.Jet.OLEDB.4.0;DATA SOURCE="
strCon = strCon & accessDB & ";"

' Hoeveel records worden er per keer getoond.
' Dit zou een gebruiker ook kunnen opgeven en met
request.form("aantalRecords") opgevraagd kunnen worden.
aantalRecords = 2

' De pagina die getoond moet worden.
if Request.QueryString("pagina") = "" Then

huidigePagina = 1

Else

huidigePagina = CInt(Request.QueryString("pagina"))

End if

' Maak een serverobject aan voor de connectie (ObjectConnectie -> objCon)
Set objCon = Server.CreateObject("ADODB.Connection")

' Maak een recordsetobject aan.
Set objRec = Server.CreateObject("ADODB.Recordset")

' Open de verbinding met de database. Voor objCon wordt er een
' verbinding geopend met opgegeven database.
objCon.Open strCon

' De SQL query om de gegevens uit de database te halen.
SQL = "SELECT * FROM klanten"

' Plaats de gegevens van de SQL Query in de recordset objRec.
' Geef de juiste constante uit adovbs.inc mee.
objRec.Open SQL, strCon, adOpenStatic, adLockReadOnly, adCmdText

' Zet het aantal records in Pagesize
objRec.PageSize = aantalRecords

' Zet het aantal records in cachesize
objRec.CacheSize = aantalRecords

' Tel het aantal pagina's
aantalPaginas = objRec.PageCount

' zorg ervoor dat de huidige pagina niet buiten het aantal pagina's valt.
if huidigePagina > aantalPaginas Then

huidigePagina = aantalPaginas

End if

if huidigePagina < 1 Then

huidigePagina = 1

End if

' Wanneer er geen records zijn geef een melding.
if aantalPaginas = 0 Then

Response.Write "Er zijn geen records gevonden"

Else

' Ga naar de juiste pagina
objRec.AbsolutePage = huidigePagina

%>

<p>
<font size="+1">Pagina<strong> <%= huidigePagina %></strong> van de <strong><%= aantalPaginas %></strong></font>
</p>

<%
' Een spatie
Response.Write vbCrLf

' Maak een tabel
Response.Write "<table border=""1"">" & vbCrLf

' Toon de namen van de velden
Response.Write "<tr>" & vbCrLf
For I = 0 To objRec.Fields.Count - 1

Response.Write "<td>"

Response.Write objRec.Fields(I).Name

Response.Write "</td>" & vbCrLf

Next
Response.Write "</tr>" & vbCrLf

' Toon de records.
recordsGetoond = 0
Do While recordsGetoond < aantalRecords And Not objRec.EOF

Response.Write "<tr>" & vbCrLf
For I = 0 To objRec.Fields.Count - 1

Response.Write "<td>"

Response.Write objRec.Fields(I)

Response.Write "</td>" & vbCrLf

Next
Response.Write "</tr>" & vbCrLf

' Verhoog het aantal records dat getoond is
recordsGetoond = recordsGetoond + 1

' Volgende record.
objRec.MoveNext
Loop

' Sluit de tabel
Response.Write "</table>" & vbCrLf

End if

' Alles afsluiten
objRec.Close
Set objRec = Nothing
objCon.Close
Set objCon = Nothing


'Maken van de volgende en vorige knoppen.

' Maak de [< Vorige] knop
if huidigePagina > 1 Then
%>

<a href="paging.asp?pagina=<%= huidigePagina - 1 %>">[&lt; Vorige]</a>

<%
End if

' Aantal pagina's tonen [1 2 3 4]
For I = 1 To aantalPaginas

if I = huidigePagina Then
%>

<%= I %>

<%
Else
%>

<a href="paging.asp?pagina=<%= I %>"><%= I %></a>

<%
End if

Next

' Maak de [Volgende >] knop
if huidigePagina < aantalPaginas Then
%>

<a href="paging.asp?pagina=<%= huidigePagina + 1 %>">[Volgende &gt;]</a>

<%
End if
%>
</body>
</html>

Klik hier voor het voorbeeld

In dit voorbeeld heet het script paging.asp. Wanneer de pagina een andere naam krijgt is het noodzakelijk om onderaan bij de volgende en vorige knoppen de naam van de pagina te wijzigen.


1 
Reacties
Reacties: Database paging (Aantal reacties: 17 )
» Nieuwe reactieView Mode : Full | Preview | Refresh
First | Previous | Next | Last
Door: GastAug 18, 06:36
' Maak een serverobject aan voor de connectie (ObjectConnectie -> objCon)
Set objCon = Server.CreateObject("ADODB.Connection")

' Maak een recordsetobject aan.
Set objRec = Server.CreateObject("ADODB.Recordset")

' Open de verbinding met de database. Voor objCon wordt er een
' verbinding geopend met opgegeven database.
objCon.Open strCon

' De SQL query om de gegevens uit de database te halen.
SQL = "SELECT * FROM klanten"

' Plaats de gegevens van de SQL Query in de recordset objRec.
' Geef de juiste constante uit adovbs.inc mee.
objRec.Open SQL, strCon, adOpenStatic, adLockReadOnly, adCmdText

Ligt het aan mij of wordt 'objCon' enkel geset en gesloten en verder niet gebruikt.
Ik gebruik meestal de 'set objRec = objCon.execute(SQL)' om de recordset aan te maken. Maar hier wordt voor de recordset een appart object gemaakt.

 (Reply...)
Door: swebdAug 4, 14:42
Hoi,

Ik heb in een pagina de paging code ingebouwd maar krijg een foutmelding voor het object AbsolutePage >>> Code: RsList.AbsolutePage = huidigePagina

-----------------------------------
FOUTMELDING:
ADODB.Recordset error '800a0cb3'

Current Recordset does not support bookmarks. This may be a limitation of the provider or of the selected cursortype.
-----------------------------------

Kent iemand hier een alternatief voor?

Alvast bedankt.
 (Reply...)
Door: nedneathMar 2, 11:15
Hoihoi,

Meerdere korte vraagjes over paging. Ten eerste: is het wel nodig om adovbs.inc te gebruiken? Volgens mij komt hij alleen terug bij het uitvoeren van de SQL?

Verder zie ik een aantal variabelen, die ik niet kan plaatsen, zoals CInt en vbCrLf; waar komen die vandaan en wat is hun functie?

Tot slot, waar kan ik de voorbeeld database downloaden. Ik kan hem niet zo snel vinden op deze site.

Bedankt
 (Reply...)
Door: nedneathMar 2, 12:35
Nogmaals ik en vergeet de vorige reactie. Het is reeds gelukt om paging aan de praat te krijgen (gecombineerd met een zoekfunctie van een andere pagina), maar nu werkt hij niet helemaal.

Wanneer ik op 'volgende' klik, springt hij direct naar de laatste pagina. Ook wanneer ik één van de tussenliggende pagina's probeer te openen, springt hij naar de laatste pagina. Vervolgens werkt de 'vorige' ook niet. Ik heb de code toegevoegd; kan iemand de fout ontdekken?

<%
Sub Show_student %>

<h1>show students</h1>

<%
Dim strcon, objcon, objrec, accessDB
Dim Keyword
Dim numrec, showrec, numpage, curpage, I

numrec = 2
showrec = 0

accessDB = server.mappath("../db/data.mdb")
strCon = "PROVIDER=Microsoft.Jet.OLEDB.4.0;DATA SOURCE="
strCon = strCon & accessDB & ";"


'---------- page display ----------

IF Request.QueryString("page") = "" Then
curpage = 1
ELSE
curpage = Request.QueryString("page")
End IF


Set objrec = Server.CreateObject ( "ADODB.RecordSet" )
Set objCon = Server.CreateObject ( "ADODB.Connection" )
objCon.Open strCon


'---------- search database on keyword ----------

Keyword = Request.Form("kw")

SELECT CASE Request.Form("radiobutton")

CASE "lastname"
SQL = "SELECT * FROM student WHERE (lastname LIKE '%" & Keyword & "%') ORDER BY lastname"

CASE "firstname"
SQL = "SELECT * FROM student WHERE (firstname LIKE '%" & Keyword & "%') ORDER BY lastname"

CASE ELSE
SQL = "SELECT * FROM student ORDER BY lastname"

END SELECT

objrec.open SQL, strCon, 3, 1



'---------- put number of records in memory ----------
objrec.Pagesize = numrec
objrec.CacheSize = numrec
numpage = objrec.PageCount


'---------- keep number of pages between limits ----------

IF curpage > numpage Then
curpage = numpage
END IF

IF curpage < 1 Then
curpage = 1
END IF


'---------- when no records are selected ----------

IF numpage = 0 Then %>

<hr>
<p><b>No students found!</b></p>
<% Exit Sub


ELSE
objrec.AbsolutePage = curpage


'---------- create table ----------
%>
<p>
<font size="+1">Page<strong> <%= curpage %></strong> of <strong><%= numpage %></strong></font>
</p>

<%
Response.Write "<table border=""1"">"


'---------- display fields ----------

Response.Write "<tr>"
For I = 0 To objRec.Fields.Count - 1

Response.Write "<td>"

Response.Write objRec.Fields(I).Name

Response.Write "</td>"

Next
Response.Write "</tr>"


'---------- display records ----------

Do While showrec < numrec And Not objRec.EOF

Response.Write "<tr>"
For I = 0 To objRec.Fields.Count - 1

Response.Write "<td>"

Response.Write objRec.Fields(I)

Response.Write "</td>"

Next
Response.Write "</tr>"

showrec = showrec + 1

objRec.MoveNext
Loop

Response.Write "</table>"

End if


'---------- make buttons and links ----------

if curpage > 1 Then
%>

<a href="default.asp?mode=showstudent&page=<%= curpage - 1 %>">[< Vorige]</a>

<%
End if

For I = 1 To numpage

if I = curpage Then
%>

<%= I %>

<%
Else
%>

<a href="default.asp?mode=showstudent&page=<%= I %>"><%= I %></a>

<%
End if

Next

if curpage < numpage Then
%>

<a href="default.asp?mode=showstudent&page=<%= curpage + 1 %>">[Volgende >]</a>

<%
End if

objrec.Close
Set objrec = Nothing
objCon.close
set objCon = Nothing

End sub
%>
 (Reply...)
Door: ocdaanDec 18, 18:38
Cool script, er zitten een paar trucjes in die ik niet kende. Bedankt he
 (Reply...)
Door: omasterDec 17, 22:19
het lukt me niet op het bestand adovbs.txt te downloaden.

zouden jullie so vriendelijk willen zijn om deze naar mij op te sturen?

alvast bedankt

gr omaster

(* edit ramon: ff je e-mail verwijderd tegen spam )
 (Reply...)
Door: Ramon (Admin)Dec 18, 06:38
Hij staat weer goed, je kan hem downloaden met rechtermuis > save target as
 (Reply...)
Door: erwinbAug 1, 10:53
geachte,

hoe moet ik nu binnen de code van paging omgaan met een image, die als tekstverwijzing wordt aangegeven in het Hyperlinkveld van mijn db.
Zonder dit stukje werkt het goed maar met plaatje zou leuk zijn.

"SELECT Objectnaam, Plaats, Locatie, Koopprijs, Soort_object, Type_woning, img border="0" src="<%= objRec.Fields("Hyperlink")

bvd
erwin
 (Reply...)
Door: Marion B.Dec 17, 12:29
Het gewone pagen werkt. Maar ik wil graag weten hoe ik het voor elkaar kan krijgen dat je niet alle paginanummers te zien krijgt als het er een heleboel zijn. Zodra het meer dan, zeg, 10 worden is het niet mooi meer om alle paginalinken te laten zien.
Ik weet dat het mogelijk is om dan een deel in "vorige" en "volgende" te stoppen, maar hoe wordt dat gedaan?
Zoals bijvoorbeeld bij Google: Vorige, 6,7,8,9,10, Volgende
 (Reply...)
Door: woutOkt 10, 14:22
Hallo,

Tis al opgelost!

 (Reply...)
Hoofdstukken
Database paging

Acties
Geen acties beschikbaar

Zoeken
Zoekterm(en):

Vevida - Internet Service Provider

Eduvision opleidingen

OrangeWebbers
Copyright © 2002-2004 Ramon Siem A Joe